Where does Debian store the list of installed packages?

Question

I need to find a list of the packages that were installed on a Debian (Armbian) sever before it died. Since it's offline, I can't use apt or dpkg (or any other command). I need to know which file(s) contain the list (even if they're binary). I tried searching, but everything just says to run the aforementioend commands, which isn't an option.

Answer 1

How to approximate `dpkg --get-selections` from a backup of /etc and /var? addresses your underlying concern.

The list of installed packages is stored in /var/lib/dpkg/status. Look for Status: install ok installed lines — this indicates that the package is correctly installed.

The following AWK invocation will extract the installed package names from a status file:

awk '/^Package:/ { package = $2 }
     /^Status: install ok installed/ { print package }' /path/to/status

If the system supported multiple architectures, you’ll need to keep track of that too:

awk '/^Package:/ { p = $2; i = 0 }
     /^Status: install ok installed/ { i = 1 }
     i && /^Architecture: all/ { print p; next }
     i && /^Architecture/ { printf "%s:%s\n", p, $2 }' /path/to/status

Another interesting file is /var/lib/apt/extended_states which records the “automatic installation” flag for installed packages. You can restore the flags by running something like

awk '/^Package:/ { p = $2 }
     /^Architecture/ { a = $2 }
     /^Auto-Installed: 1/ { printf "%s:%s\n", p, a }' /path/to/extended_states |
xargs sudo apt-mark auto

You can combine both files to list the packages that were manually installed, and rely on dependency management to install the automatically-installed packages (although this won’t necessarily result in the same set of packages being installed):

awk 'FNR == NR && /^Package:/ { p = $2 }
     /^Status: install ok installed/ { i = 1 }
     FNR == NR && i && /^Architecture: all/ { ps[p] = 1; next }
     FNR == NR && i && /^Architecture/ { ps[p ":" $2] = 1}
     FNR != NR && /^Package:/ { p = $2 }
     FNR != NR && /^Architecture:/ { a = $2 }
     /^Auto-Installed: 1/ { delete ps[p ":" a] }
     END { for (p in ps) print p }' /path/to/status /path/to/extended_states

See the “FILES” section in man dpkg:

/var/lib/dpkg/status
Statuses of available packages. This file contains information about whether a package is marked for removing or not, whether it is installed or not, etc.