2

I have a problem parsing Xml from a third party; there are several different versions of the xml which they send, with overlapping namespaces;

Version 1

foo="urn:bar.org/version-1"

far="urn:gle.org/version-1"

Version 2

foo="bar:a.org/version-2"

far="gle:a.org/version-2"

Previously (when I was only had to handle one version) I'd register the namespaces from a hardcoded hash like so:

#!/usr/bin/perl

use strict;
use XML::LibXML ;

my $cfg->{namespace} = {
    foo=>"urn:bar.org/version-1",
    far=>"urn:gle.org/version-1",
};

my $parser = XML::LibXML->new({recover => '1'});

my $doc = $parser->parse_string($inputHash->{$key}->{xml});

my $xc = XML::LibXML::XPathContext->new( $doc->documentElement() );

for my $ns (keys %{$cfg->{namespace}})
{
    $xc->registerNs($ns => $cfg->{namespace}->{$ns});
}

obviously this will only work on version 1..

Have scoured the LibXML documentation but can't see a way to extract the namespaces used in a doc and register them; could anyone give me a pointer please?

Pseudo doc:

<?xml version="1.0"?>
<foo:Parent xmlns:soapenv="http://schemas.xmlsoap.org/soap/envelope/" xmlns:foo="bar:a.org/version-2">
    <far:Child xmlns:gle="gle:a.org/version-2">
    {horrific structure with more ns declarations all of which need registering}
    </far:Child>
</foo:Parent>
beresfordt
  • 5,088
  • 10
  • 35
  • 43
  • That's some crazy schema if the namespace is unpredictable! You shouldn't have to deal with that. – ikegami Sep 12 '11 at 15:49
  • I know, but shouldn't isn't an option.. It's the work of a major telecoms company - shame on them! – beresfordt Sep 12 '11 at 16:32
  • Yeah, I was just empathising. Note that XPath `name("moo")` will match elements `moo` from any namespace. It might be useful in locating the element whose namespace you want to identify. – ikegami Sep 12 '11 at 16:48

3 Answers3

9

Going off of this answer, I would use the //namespace::* XPath expression to find the namespaces. Try this code sample and see if it helps:

use strict;
use warnings;
use XML::LibXML;

my $cfg;
my $xml = XML::LibXML->load_xml( location => <your xml>);
foreach my $node ($xml->findnodes('//namespace::*')) {

    $cfg->{namespace}{$node->getLocalName()} = $node->getValue();
}

This should populate your hash with what you need. Also, this XPath expression is not always supported. I tested this using LibXML 1.70, and dll version 20703 and it worked for me.

Community
  • 1
  • 1
Joel
  • 3,435
  • 2
  • 23
  • 33
  • Thanks - this works for the namespaces declared in the parent tag, but doesn't pick up those declared deeper in the tree. Will go through that thread and see if I can get something from it. Updating question with psuedo xml :) – beresfordt Sep 12 '11 at 16:22
  • ahha - changing the findnodes expression to: '//*/namespace::*' does it! Many thanks - you've saved me from some horrors :) – beresfordt Sep 12 '11 at 16:38
0

I'd try XML::LibXML::Node::lookupNamespaceURI, i.e.

$cfg->{namespace}->{foo} = $node->lookupNamespaceURI("foo");

for some node deep enough so that it has the declaration. The simplest node to use would be the document, but that won't work unless the namespace is declared at the top; the most general approach would be going through all the nodes, and handling the case of the same prefix being reused for different namespaces according to your application logic...

vbar
  • 61
  • 1
  • Thanks, but this will still require declaring 'foo' 'bar' etc - I'd rather stay away from hardcoding anything so I dont need to revisit this! – beresfordt Sep 12 '11 at 16:14
  • Well, you can get the prefixes from node names - just split them on ':'. But I don't think it's possible to make a script handling every future change in its input format... – vbar Sep 12 '11 at 17:32
0

you iterate over the tree looking for namespaces until you find one, say using getElementsByTagName or some such

#!/usr/bin/perl --

use strict;
use warnings;

use XML::Twig;

my $xml = <<'__XML__';
<?xml version="1.0"?>
<!-- initially, the default namespace is "books" -->
<book xmlns='urn:loc.gov:books'
      xmlns:isbn='urn:ISBN:0-395-36341-6'>
    <title>Cheaper by the Dozen</title>
    <isbn:number>1568491379</isbn:number>
    <notes>
      <!-- make HTML the default namespace for some commentary -->
      <p xmlns='urn:w3-org-ns:HTML'>
          This is a <i>funny</i> book!
      </p>
    </notes>
</book>
__XML__

{
    my $t = XML::Twig->new(
        start_tag_handlers => {
            _all_ => sub {
                my $tag = $_[1]->tag;
                my $nsp = $_[1]->ns_prefix||'';
                print "$tag => $nsp\n";
                print map {
                    join ' ',
                        "\t", $_,' => ', $_[1]->att($_), "\n"
                    } grep /xmlns/ , $_[1]->att_names ;
            },
        },
    );
    $t->parse($xml);
}
__END__
book =>
         xmlns  =>  urn:loc.gov:books
         xmlns:isbn  =>  urn:ISBN:0-395-36341-6
title =>
isbn:number => isbn
notes =>
p =>
         xmlns  =>  urn:w3-org-ns:HTML
i =>
twiggys
  • 1