Datagridview doesn't refresh even after reassigning its datasource to bindingsource

Question

I have 3 different datagridviews all bound to a separate bindingsource. I would like to update the datagridviews when new data is loaded into the bindingsources. I have tried the generally accepted method for solving this problem here:

1.) Create a Binding Source

2.) Set the Datasource for this object to your Dataset Table.

3.) Set The datasource for your DatagridView as the Binding source Object.

bindingsrc.DataSource = newDataTable;

// The two lines below were supposedly a dirty solution to refreshing the grid.

dg1.DataSource = null;
dg1.DataSource = bindingsrc;

However it doesn't work. I have also tried to reset the bindings for each bindingsource:

bindingsrc.ResetBindings();

but to no avail. I know I am getting the correct new data, because once I step into the code when debugging, newDataTable has the correct new data. So it is a matter of the datagridview not refreshing. In case this might be relevant, my datagridviews are part of a panel whose parent is a splitcontainer. I have also tried to refresh the parent:

this.dataGridView.Parent.Refresh()

without any results.

Answer 1

I found the solution to my problem. I did not need to handle the BindingContext_Changed event, and the general methodology of:

bindingSource1.ResetBindings(false);
dataGridView1.DataSource = null;
bindingSource1.DataSource = null;
bindingSource1.DataSource = mytable;
dataGridView1.DataSource = bindingSource1;

was the correct way to update the grid.

The real problem: From my original question: "In case this might be relevant, my datagridviews are part of a panel whose parent is a splitcontainer." The following line of code:

 split.Panel2.Controls.Add(new ConfigurableMatrices(comboBox1.SelectedItem.ToString(), comboBox2.SelectedItem.ToString())); 

was re-adding this class (ConfigurableMatrices, which is the one which has my datagridviews in it) with all its controls to the second panel of the splitcontainer parent. This line of code is executed from the other half of the splitcontainer. I was also refreshing after that:

split.Panel2.Controls.Add(new ConfigurableMatrices(comboBox1.SelectedItem.ToString(),  
comboBox2.SelectedItem.ToString()));
split.Panel2.Refresh();

However this way, I was only adding a new class (ConfigurableMatrices) each time on top, and this didn't for some reason correctly update. The solution which works for me right now is to call the Dispose method just before the above two lines of code:

foreach (Control control in split.Panel2.Controls)
        {
            control.Dispose();
        }
split.Panel2.Controls.Add(new ConfigurableMatrices(comboBox1.SelectedItem.ToString(), comboBox2.SelectedItem.ToString()));
split.Panel2.Refresh();

I'm hoping the Dispose method is the correct way to tackle this and won't trigger other problems in the future.

Answer 2

Under normal circumstances no refresh is needed. The following opens a Microsoft NorthWind database, loads all table names into a ComboBox with DropDownStyle = DropDownList. Select a table name in the ComboBox, press the button and our DataGridView is then loaded. I bypassed using a DataSet but that will not make a difference other then DataMember property of the DataGridView which if not set could cause the issue at hand so best to check Datamember is correct.

Code to get table names and give us our connection string no matter .accdb or .mdb

In this code we use SELECT * but of course in a real app we alone select the fields needed for a specific operation unless there is a need to see all fields.

Imports System.Data.OleDb
Public Class SchemaInfo
    Private Shared _Instance As SchemaInfo
    Public Shared Function GetInstance() As SchemaInfo
        If _Instance Is Nothing Then
            _Instance = New SchemaInfo
        End If
        Return _Instance
    End Function
    Protected Sub New()
    End Sub
    Private Shared _ConnectionString As String
    Public Function ConnectionString() As String
        Return _ConnectionString
    End Function
    Public Function TableNames(ByVal DatabaseName As String) As List(Of String)
        Dim Names As New List(Of String)

        Using cn As New OleDbConnection(BuildConnectionString(DatabaseName))
            _ConnectionString = cn.ConnectionString
            cn.Open()

            Dim dt As DataTable = cn.GetSchema("Tables", New String() {Nothing, Nothing, Nothing, "Table"})

            For Each row As DataRow In dt.Rows
                Names.Add(row.Field(Of String)("Table_Name"))
            Next

        End Using

        Return Names

    End Function
    <System.Diagnostics.DebuggerStepThrough()> _
    Private Shared Function BuildConnectionString(ByVal DatabaseName As String) As String

        If IO.Path.GetExtension(DatabaseName).ToLower = ".accdb" Then

            Dim Builder As New OleDb.OleDbConnectionStringBuilder With
                {
                    .Provider = "Microsoft.ACE.OLEDB.12.0",
                    .DataSource = DatabaseName
                }

            Return Builder.ConnectionString

        ElseIf IO.Path.GetExtension(DatabaseName).ToLower = ".mdb" Then

            Dim Builder As New OleDb.OleDbConnectionStringBuilder With
                {
                    .Provider = "Microsoft.Jet.OLEDB.4.0",
                    .DataSource = DatabaseName
                }

            Return Builder.ConnectionString

        Else

            Throw New Exception("File type not supported")

        End If

    End Function
End Class

Form code

Imports System.Data.OleDb

Public Class SwitchTableOnBindingSourceForm
    WithEvents bsData As New BindingSource
    Private Sub SwitchTableOnBindingSourceForm_Load(
        sender As Object, e As EventArgs) Handles MyBase.Load

        cboTables.DataSource = SchemaInfo.GetInstance.TableNames(
            IO.Path.Combine(
                AppDomain.CurrentDomain.BaseDirectory, "NorthWind.accdb"))

        DataGridView1.DataSource = bsData

    End Sub
    Private Sub cmdSelectTable_Click(
        sender As Object, e As EventArgs) Handles cmdSelectTable.Click

        Dim dt As New DataTable
        Using cn As New OleDbConnection(SchemaInfo.GetInstance.ConnectionString)
            Using cmd As New OleDbCommand("SELECT * FROM " & cboTables.Text, cn)
                cn.Open()
                dt.Load(cmd.ExecuteReader)
            End Using
        End Using

        bsData.DataSource = dt

    End Sub
End Class